BUCL.io / implode

Verbindet mehrere Texte zu Einem.

Beispiel

{res} implode "," "one" "two" "three"

Quellcode

#implode
#description: Concats multiple texts into one.
#description-DE: Verbindet mehrere Texte zu Einem.
#sample: {res} implode "," "one" "two" "three"
#to test direct: {input} = "," "we" "are" "simple" "texts"

#read input numbered and named
{glue} = ""
{parts} = {input}
{inputCount} count {input}
if {inputCount} >= 2
	{glue} = {input/0}
	{parts} slice 1 0 {input}
if {input/glue}
	{glue} = {input/glue}
if {input/parts}
	{parts} = {input/parts}

#make flat numeric list of all parameters (incl. named onces)
{flat} = ""
{loop} each {parts}
	if {loop/first}
		{flat} = {loop/value}
	else
		{flat} = {flat} {loop/value}
{result} = ""
{loop} each {flat}
	if {loop/first}
		{result} = {loop/value}
	else
		{result} = "{result}{glue}{loop/value}"
{output} = {result}

Kurzreferenz

Syntax (Schreibweise)
#
Kommentar im Script.
#Ich bin ein Kommentar
funktion
Ein Funktionsname. Steht immer am Anfang der Befehlszeile und ruft eine bestimmte Funktion auf.
length
"Texte"
Texte oder auch Zahlen sollten immer in doppelten Hochkomma stehen und dienen als Parameter (Werte) einer Funktion.
length "Hallo Welt."
{...}
Variablen. Zum Einspeichern immer am Anfang der Befehlszeile noch vor der Funktion. Zum Auslesen an der gewünschten Stelle.
{var1} length "Hallo Welt."
{var2} = "Länge ist: {var1}"
Eingebaute Funktionen
=
Speichert Texte unverändert in eine Variable.
{variable} = "Text1" "Text2"
random
Generiert eine zufällige ganze Zahl. Optional in einem bestimmten Zahlenbereich.
{r} random 0 10
math
Berechnet einen mathematischen Ausdruck.
{m} math "3+3"
count
Zählt die Anzahl der Parameter.
{c} count "eins" "zwei"
length
Zählt die Zeichen der Parameter.
{l} length "hal" "lo"
Eingebaute Logiken
if
Prüft eine Texte oder Variablen auf einen bestimmten Inhalt.
if "Text" = "Text"
	{res} = "Text ist gleich Text"
elseif
Prüft eine Texte oder Variablen auf einen bestimmten Inhalt, wenn die vorherige Prüfung nicht erfolgreich war.
if "Text" = "Anderes"
	{res} = "Text ist gleich Text"
elseif "Text" = "Text"
	{res} = "Irgendwas anderes"
else
Ermöglicht Befehle auszuführen, wenn die vorherige Prüfung nicht erfolgreich war.
if "Text" = "Anderes"
	{res} = "Text ist gleich Text"
else
	{res} = "Irgendwas anderes"
repeat
Wiederholt nachfolgende eingerückte Befehlszeilen eine bestimmte Anzahl mal.
{r} repeat 5
	{res} = "{r/index} von 5 mal Hallo!"
each
Wiederholt nachfolgende eingerückte Befehlszeilen für jeden als Parameter übergebenden Text.
{e} each "Hans" "Peter" "Marie"
	{res} = "Hallo {e/value}!"
Funktionen der Bibliothek
explode
Trennt einen Text in mehrere Texte auf.
{res} explode "," "one,two,three"
implode
Verbindet mehrere Texte zu Einem.
{res} implode "," "one" "two" "three"
maxlength
Zählt die Zeichen des längsten Parameters.
{res} maxlength "ha" "llo"
readfile
Liest den Inhalt einer Datei.
{res} readfile "test.txt"
reverse
Dreht eine Zeichenkette um.
{res} reverse "ollaH"
slice
Schneidet einen Teil aus einer Liste.
{res} slice 1 -1 "cut" "use" "cut"
substr
Schneidet einen Teiltext aus einem Text heraus.
{res} substr 0 3 "AAAaaa"
writefile
Schreibt bzw. überschreibt den Inhalt einer Datei.
{res} writefile "test.txt" "Sample content"